先锋教育日志-运用比喻的方法进行传授的力量

运用比喻的方法进行传授的力量

　　一个很有意思的flash教程。我们从中可以看到运用比喻的方法进行传授的力量。教程来自闪客帝国。
　　趣味教程:从女娲造人谈类、属性、方法及实例(1)
　　前言:相信大家都听说过女娲造人的故事，不过细节可能不会太清楚，我现在略述如下，您可要仔细听哦，这和我们今天要聊的主题有莫大的关系呀。
　　女娲是一个人身龙尾的女神。盘古开天辟地以后，也就在天地间到处游历。她虽然是神，可是也会寂寞的，望着平静的水面里自己美丽的倒影不胜唏嘘。于是她便决定按照自己的形貌来捏泥人。女娲心灵手巧，不一会儿就捏好了好多的泥人。这些泥人几乎和她一样，只不过她给他们做了与两手相配的双腿，来代替龙的尾巴。女娲朝着那些小泥人吹口气，那些小泥人便被灌注了活力，“活”了起来，变成了一群能直立行走、能言会语、聪明灵巧的小东西，女娲称他们为“人”。女娲在其中一些人身上注入了阳气——自然界一种好斗的雄性要素，于是他们就成了男人；而在另外一些人身上，她又注入了阴气——自然界一种柔顺的雌性素，于是她们便成了女人。女娲想让人们遍布广阔的大地，但她累了，做得也太慢了。于是，她想出一条捷径。她把一根绳子放进河底的淤泥里转动着，直到绳的下端整个儿裹上一层土。接着，她提起绳子向地面上一挥，凡是有泥点降落的地方，那些泥点就变成了一个个小人。女娲就这样创造了布满大地的人们。
　　这个故事可谓是蕴涵了极深刻的程序语法规则，大家看完我下面的分析后，一定会相信故事的作者没准是远古时代的程序员呢!
　　<代码看起来很长，是我加了详细的注释的缘故>
　　1、类:如果女娲属于一个类的话，可以称之为"神"。代码表示为:
　　--神.as开始--
　　

class 神{
//class :定义'类'的关键字,描述一组具有共性的对象的特征
    static var 类别:String="神";
   //static :定义'类变量'或'类方法'的关键字,它描述一组类的整体属性或方法。在这里表示，所有的神的都可称为"神"。
    static var 所属:Object =神;//表示神归谁管啦，中国远古的神好象没有什么附属关系哦。
    public var 善恶:String;
   //public :定义'公开'属性或方法的关键字，它描述类的可以供外部对象访问的属性或方法。
    private var __姓名:String;
   //private :定义'私有‘属性或方法的关键字,它描述类的需要封装的属性或方法,
   //表现为它定义的变量或方法只可以被类或子类内部的方法访问(调用).
   //下面会详细说明用private的理由的.
   private var __形体:String;//在变量名字前加"__"仅标志它是具有获取/设置方法的属性.
   private var __性别:String;
   public function set 姓名(n:String):Void{
   //set:动作脚本 2.0中隐式设置类相关属性的关键字.下面会详细说明
        __姓名=n;//类内部的方法可以访问私有属性'__姓名'
  }
   public function get 姓名():String{
   //get:动作脚本 2.0中隐式获取类相关属性的关键字.下面会详细说明
       var n:String="伟大的神"+__姓名;//类内部的方法可以访问私有属性'__姓名'
       return n;
   }
   public function set 形体(x:String):Void{
      __形体="神奇的"+x;
   }
   public function get 形体():String{
      return __形体;
   }
   public function set 性别(n:String):Void{
      if(n=="男"||n=="女"){
              __性别=n;
      }
   } 
   public function get 性别():String{
              return __性别;
   }
   function 神(sh:String,n:String,x:String,s:String){
   //构造函数,是连接类和实例的纽带,它接受外部设置的参数,
  //对即将生成的实例进行初始化.它的表现就是名称与包含它的类的名称相同.其实我真的认为...它可以比喻为'子宫'的..
   //sh:善恶,n:姓名,x:形体,s:性别
      善恶=sh;//为善恶属性直接赋值。
      姓名=n;//调用'set 姓名'方法为'__姓名'属性赋值。
      形体=x;//调用'set 形体'方法为'__形体'属性赋值。
      性别=s;
    //调用'set 性别'方法为'__性别'属性赋值，在赋值之前会先判断s是否为'男'或'女'。
    //对赋值进行必要的控制，是隐式设置属性的一个优势。
   }
   public function 寂寞():Void{
      trace("\"自己好孤单啊，有个人陪陪我多好啊!\"");
      //为什么不去[维艺--Flash]论坛?呵呵，做个广告啦!
   }
   public function 创造(o:String):Object {
   //o:创造的目标
      if(o=="人"){
          var 泥人=捏泥人();
          var 气=["阳","阴"];
          var r=Math.floor(Math.random()*2);//得到一个随即数字,或0或1
          var 随即气= 气[r];
          var 人=吹口气(泥人,随即气);//类内部的方法可以调用'私有'方法'吹口气'
          命名(人,"人");//女娲称他们为'人'...
          return 人;
       }
       //if ... 当然神还具备其它的创造本领，这里略~
    }
     public function 捏泥人():Object {
        trace("捏泥人...");
        var 泥人=new Object();
        泥人.形体="人身人腿";//据上面神话所述，女娲是'人身蛇尾'...
        trace("一个泥人制作完毕!");
        return 泥人;
    }
    public function 命名(o:Object,n:String){
    //o:待命名的对象,n:名称
        o.类别=n;
        trace("一个人诞生了!");
    }
    private function 吹口气(o:Object,s:String):Object{
    //o:泥人,s:气
    //这个方法确实是神私有的方法啦，我一直都不理解的，如果能吹口气吹出银子来...
    trace("吹口气...");
   //--泥人具有了以下本领--
    o.直立行走=function(){
              trace("打架摔交中...");
    }
    trace("泥人学会直立行走!");
    o.能言会语=function(){
    trace("谈情说爱中...");
  }
  trace("泥人学会语言!");
  o.聪明灵巧=function(){
              trace("坑蒙拐骗中...");
  }
  trace("泥人学会思考!");
   //呵呵
   if(s=="阴"){
   //如果注入的是阴气
              o.性别="女";
   }else if(s=="阳"){
              o.性别="男";
   }
   //else if 又阴又阳 then 人妖~~
   trace("泥人性别是"+o.性别+"!");
   trace("泥人具备了灵魂!");
   return o;
  }
}

　　--神.as结束--
　　到这里我们的"造神运动"就告一阶段了，该看看我们的神的威力啦！
　　--女娲造人.fla开始--
　　

//在第一桢上写代码:
var 女娲=new 神("善","女娲","人身蛇尾","女");
//new:生成实例的关键字，它先创建一个初始时匿名的新对象，再用构造函数设置新对象的特性，
//最后返回新对象的内存地址。在这里新诞生的'神'的内存地址赋给了'女娲'变量。
trace(女娲.姓名+"是一位"+女娲.形体+女娲.性别+神.类别);
//调用女娲的'get 姓名'方法,返回'伟大的神女娲'。对返回的属性值进行必要的控制，是隐式获取属性的一个优势。
//比如，你的老板叫张三，却常被称为'张总'，这也是经过必要的控制之后得到的结果。
//'张三'这个名字只有他的自己人才使用哦！所以说生活中有很多事情也可用'私有属性'来解释的~
trace("她是"+女娲.善恶+神.类别);
//直接返回女娲的善恶属性值。
trace("一天,她觉得");
女娲.寂寞();
trace("于是,她开始");
女娲.创造("人");

　　--女娲造人.fla结束--
　　现在测试一下吧，看看会产生什么惊天动地的大事吧!
　　--测试影片开始--
　　伟大的神女娲是一位神奇的人身蛇尾女神
　　她是善神
　　一天,她觉得
　　"自己好孤单啊，有个人陪陪多好啊!"
　　于是,她开始
　　捏泥人...
　　一个泥人制作完毕!
　　吹口气...
　　泥人学会直立行走!
　　泥人学会语言!
　　泥人学会思考!
　　泥人性别是男!
　　泥人具备了灵魂!
　　一个人诞生了!
　　--测试影片结束--

　　呵呵，到此为止，我们的女娲造人的故事就讲述了一半了，接下来就该女娲如何用绳子甩泥点造人啦(这的确比一个一个手工捏要利索多了),也就是类的继承。希望不会让大家等太久哦:)

先锋教育日志

学习·思考·探究·实践

导航

2006-4-23 21:38:8

运用比喻的方法进行传授的力量

Tags: 比喻

发布:edupioneer | 分类:教育随想 | 评论:1 | 引用:101 |

日历

最新留言

最近发表

Powered By Z-Blog 1.5 Build 60101

Copyright edupioneer Some Rights Reserved.